#!/bin/csh
#
#    Script file which does ALL of the work!!
#
#    quick_run 0     ==>  reads two_exp_fit_ranges.dat and makes the
#                         fitting scripts
#
#    quick_run 1     ==>  performs all of the fits using the scripts
#                         made by quick_run 0
#
#    quick_run 2     ==>  makes the web pages
#
#    quick_run 3     ==>  makes all of the plots with respect to R
#
#
###########################################

set runs = ( 11 )
set orientations = ( 0 )
set webpagerun = 4
set webpagename = B24_AR5_small
set runname = C2
set nspacedim = 3
set weborientation = 0
set Nboot = 1024
set Nbootgap = 512

set program1 = /home1/old/STATIC_POTENTIAL_RESULTS/src/make_su3_scripts
set program2 = /home1/old/STATIC_POTENTIAL_RESULTS/src/make_su3_gap_scripts
set program3 = /home1/old/STATIC_POTENTIAL_RESULTS/src/make_web_pages
set program4 = /home1/old/STATIC_POTENTIAL_RESULTS/src/plot_su3_Rcurves

set a1g = 1
set a1u = 2
set a2g = 3
set a2u = 4
set b1g = 5
set b1u = 6
set b2g = 7
set b2u = 8
set eg  = 9
set eu  = 10

if ( $#argv == 0 ) then
  set flag = -2
else
  set flag = $1
endif

set locs     =  ( A1g   A1g   A1g   A1u   A2g   A2u   B1g   B1g   B1u   B2g   B2g   B2u   Eg   Eg   Eg   Eu   Eu   Eu   Eu  )
set channels =  ( $a1g  $a1g  $a1g  $a1u  $a2g  $a2u  $b1g  $b1g  $b1u  $b2g  $b2g  $b2u  $eg  $eg  $eg  $eu  $eu  $eu  $eu )
set levels   =  ( 1     2     3     1     1     1     1     2     1     1     2     1     1    2    3    1    2    3    4   )

# ***************************************************************************************

if ( $flag == -1 ) then

rm -f A1g/*
rm -f A2g/*
rm -f A1u/*
rm -f A2u/*
rm -f B1g/*
rm -f B2g/*
rm -f B1u/*
rm -f B2u/*
rm -f Eg/*
rm -f Eu/*
rm -f plots/*
rm -f Rlinks/*
rm -f *.html
rm -f *results.dat

# ***************************************************************************************

else if ( $flag == 0 ) then

foreach count ( 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 )
  if !( -d $locs[$count] ) then
     mkdir $locs[$count]
  endif
  cd $locs[$count]
  foreach run ( 1 )
  $program1 << END
  $Nboot
  $runs[$run]
  $channels[$count]
  $levels[$count]
END
  end
  cd ..
end

foreach count ( 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 )
  if !( -d $locs[$count] ) then
     mkdir $locs[$count]
  endif
  cd $locs[$count]
  foreach run ( 1 )
  $program2 << END
  $Nbootgap
  $runs[$run]
  $channels[$count]
  $levels[$count]
END
  end
  cd ..
end

# ***************************************************************************************

else if ( $flag == 1 ) then

foreach run ( 1 )

  if ( $orientations[$run] == 0 ) then
     set ending = .csh
  else if ( $orientations[$run] == 1 ) then
     set ending = _PD.csh
  else if ( $orientations[$run] == 2 ) then
     set ending = _CD.csh
  else
     echo "Bad orientation"
     exit
  endif
  foreach count ( 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 )
    cd $locs[$count]
    set runfile = fit_${locs[$count]}
    @ pcount = ${levels[$count]} - 1
    while ( $pcount > 0 )
      set runfile = ${runfile}p
      @ pcount--
      end
    set runfile = ${runfile}${ending}
    $runfile
    cd ..
    end
  foreach count ( 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 )
    cd $locs[$count]
    set runfile = fit_${locs[$count]}
    @ pcount = ${levels[$count]} - 1
    while ( $pcount > 0 )
      set runfile = ${runfile}p
      @ pcount--
      end
    set runfile = ${runfile}_gap${ending}
    $runfile
    cd ..
    end
    
  end

# **************************************************************************************

else if ( $flag == 2 ) then

if !( -d Rlinks ) then
   mkdir Rlinks
endif
$program3 << END
$cwd
$webpagename
$runname
$nspacedim
$weborientation
END

# ***************************************************************************************

else if ( $flag == 3 ) then

if !( -d plots ) then
   mkdir plots
endif
$program4 << END
$webpagerun
END

# **************************************************************************************

else

   echo " flag is not 0, 1, 2, or 3 --- nothing to do"
   
endif

exit